1 TARGET     = QtOpenGL

     2 QPRO_PWD   = $$PWD

     3 QT         = core gui

     4 DEFINES   += QT_BUILD_OPENGL_LIB

     5 DEFINES   += QT_NO_USING_NAMESPACE

     6 win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x63000000

     7 solaris-cc*:QMAKE_CXXFLAGS_RELEASE -= -O2

     8 

     9 unix:QMAKE_PKGCONFIG_REQUIRES = QtCore QtGui

    10 

    11 include(../qbase.pri)

    12 

    13 !win32:!embedded:!mac:CONFIG	   += x11

    14 contains(QT_CONFIG, opengl):CONFIG += opengl

    15 contains(QT_CONFIG, opengles1):CONFIG += opengles1

    16 contains(QT_CONFIG, opengles1cl):CONFIG += opengles1cl

    17 contains(QT_CONFIG, opengles2):CONFIG += opengles2

    18 contains(QT_CONFIG, egl):CONFIG += egl

    19 

    20 HEADERS += qgl.h \

    21 	   qgl_p.h \

    22 	   qglcolormap.h \

    23 	   qglpixelbuffer.h \

    24            qglpixelbuffer_p.h \

    25 	   qglframebufferobject.h  \

    26            qglframebufferobject_p.h  \

    27            qglextensions_p.h \

    28            qglpaintdevice_p.h \

    29 

    30 

    31 SOURCES	+= qgl.cpp \

    32 	   qglcolormap.cpp \

    33 	   qglpixelbuffer.cpp \

    34 	   qglframebufferobject.cpp \

    35            qglextensions.cpp \

    36            qglpaintdevice.cpp \

    37 

    38 

    39 !contains(QT_CONFIG, opengles2) {

    40     HEADERS += qpaintengine_opengl_p.h

    41     SOURCES += qpaintengine_opengl.cpp

    42 }

    43 

    44 !contains(QT_CONFIG, opengles1):!contains(QT_CONFIG, opengles1cl) {

    45     HEADERS +=  qglshaderprogram.h \

    46                 qglpixmapfilter_p.h  \

    47                 qgraphicsshadereffect_p.h \

    48                 qgraphicssystem_gl_p.h \

    49                 qwindowsurface_gl_p.h \

    50                 qpixmapdata_gl_p.h \

    51                 gl2paintengineex/qglgradientcache_p.h \

    52                 gl2paintengineex/qglengineshadermanager_p.h \

    53                 gl2paintengineex/qgl2pexvertexarray_p.h \

    54                 gl2paintengineex/qpaintengineex_opengl2_p.h \

    55                 gl2paintengineex/qglengineshadersource_p.h \

    56                 gl2paintengineex/qglcustomshaderstage_p.h \

    57                 gl2paintengineex/qtriangulatingstroker_p.h \

    58                 gl2paintengineex/qtextureglyphcache_gl_p.h

    59 

    60     SOURCES +=  qglshaderprogram.cpp \

    61                 qglpixmapfilter.cpp \

    62                 qgraphicsshadereffect.cpp \

    63                 qgraphicssystem_gl.cpp \

    64                 qwindowsurface_gl.cpp \

    65                 qpixmapdata_gl.cpp \

    66                 gl2paintengineex/qglgradientcache.cpp \

    67                 gl2paintengineex/qglengineshadermanager.cpp \

    68                 gl2paintengineex/qgl2pexvertexarray.cpp \

    69                 gl2paintengineex/qpaintengineex_opengl2.cpp \

    70                 gl2paintengineex/qglcustomshaderstage.cpp \

    71                 gl2paintengineex/qtriangulatingstroker.cpp \

    72                 gl2paintengineex/qtextureglyphcache_gl.cpp

    73 

    74 }

    75 

    76 x11 {

    77     contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles1cl)|contains(QT_CONFIG, opengles2) {

    78         SOURCES +=  qgl_x11egl.cpp \

    79                     qglpixelbuffer_egl.cpp \

    80                     qgl_egl.cpp \

    81                     qpixmapdata_x11gl_egl.cpp \

    82                     qwindowsurface_x11gl.cpp

    83 

    84         HEADERS +=  qgl_egl_p.h \

    85                     qpixmapdata_x11gl_p.h \

    86                     qwindowsurface_x11gl_p.h

    87 

    88     } else {

    89         SOURCES +=  qgl_x11.cpp \

    90                     qglpixelbuffer_x11.cpp

    91     }

    92 

    93     contains(QT_CONFIG, fontconfig) {

    94         contains(QT_CONFIG, system-freetype) {

    95             embedded:CONFIG += opentype

    96             # pull in the proper freetype2 include directory

    97             include($$QT_SOURCE_TREE/config.tests/unix/freetype/freetype.pri)

    98             LIBS_PRIVATE += -lfreetype

    99         } else {

   100             ### Note: how does this compile with a non-system freetype?

   101 	    # This probably does not compile

   102         }

   103     } else {

   104         DEFINES *= QT_NO_FREETYPE

   105     }

   106 

   107     LIBS_PRIVATE += $$QMAKE_LIBS_DYNLOAD

   108 }

   109 

   110 mac {

   111     OBJECTIVE_SOURCES += qgl_mac.mm \

   112                          qglpixelbuffer_mac.mm

   113     LIBS_PRIVATE += -framework AppKit -framework Carbon

   114 }

   115 win32:!wince*: {

   116     SOURCES += qgl_win.cpp \

   117 	       qglpixelbuffer_win.cpp

   118 }

   119 wince*: {

   120     SOURCES += qgl_wince.cpp \

   121                qglpixelbuffer_egl.cpp \

   122                qgl_egl.cpp

   123 

   124     HEADERS += qgl_cl_p.h \

   125                qgl_egl_p.h \

   126 }

   127 

   128 embedded {

   129     SOURCES += qgl_qws.cpp \

   130                qglpixelbuffer_egl.cpp \

   131                qglscreen_qws.cpp \

   132                qglwindowsurface_qws.cpp \

   133                qgl_egl.cpp

   134 

   135     HEADERS += qglscreen_qws.h \

   136                qglwindowsurface_qws_p.h \

   137                qgl_egl_p.h

   138 

   139     contains(QT_CONFIG, fontconfig) {

   140         include($$QT_SOURCE_TREE/config.tests/unix/freetype/freetype.pri)

   141     } else {

   142        DEFINES *= QT_NO_FREETYPE

   143     }

   144 }

   145 

   146 INCLUDEPATH += ../3rdparty/harfbuzz/src