1 /****************************************************************************

     2 **

     3 ** Copyright (C) 2010 Nokia Corporation and/or its subsidiary(-ies).

     4 ** All rights reserved.

     5 ** Contact: Nokia Corporation (qt-info@nokia.com)

     6 **

     7 ** This file is part of the QtGui module of the Qt Toolkit.

     8 **

     9 ** $QT_BEGIN_LICENSE:LGPL$

    10 ** No Commercial Usage

    11 ** This file contains pre-release code and may not be distributed.

    12 ** You may use this file in accordance with the terms and conditions

    13 ** contained in the Technology Preview License Agreement accompanying

    14 ** this package.

    15 **

    16 ** GNU Lesser General Public License Usage

    17 ** Alternatively, this file may be used under the terms of the GNU Lesser

    18 ** General Public License version 2.1 as published by the Free Software

    19 ** Foundation and appearing in the file LICENSE.LGPL included in the

    20 ** packaging of this file.  Please review the following information to

    21 ** ensure the GNU Lesser General Public License version 2.1 requirements

    22 ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.

    23 **

    24 ** In addition, as a special exception, Nokia gives you certain additional

    25 ** rights.  These rights are described in the Nokia Qt LGPL Exception

    26 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.

    27 **

    28 ** If you have questions regarding the use of this file, please contact

    29 ** Nokia at qt-info@nokia.com.

    30 **

    31 **

    32 **

    33 **

    34 **

    35 **

    36 **

    37 **

    38 ** $QT_END_LICENSE$

    39 **

    40 ****************************************************************************/

    41 

    42 /****************************************************************************

    43  **

    44  ** Copyright (c) 2007-2008, Apple, Inc.

    45  **

    46  ** All rights reserved.

    47  **

    48  ** Redistribution and use in source and binary forms, with or without

    49  ** modification, are permitted provided that the following conditions are met:

    50  **

    51  **   * Redistributions of source code must retain the above copyright notice,

    52  **     this list of conditions and the following disclaimer.

    53  **

    54  **   * Redistributions in binary form must reproduce the above copyright notice,

    55  **     this list of conditions and the following disclaimer in the documentation

    56  **     and/or other materials provided with the distribution.

    57  **

    58  **   * Neither the name of Apple, Inc. nor the names of its contributors

    59  **     may be used to endorse or promote products derived from this software

    60  **     without specific prior written permission.

    61  **

    62  ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS

    63  ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT

    64  ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR

    65  ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR

    66  ** CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,

    67  ** EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,

    68  ** PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR

    69  ** PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF

    70  ** LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING

    71  ** NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS

    72  ** SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

    73  **

    74  ****************************************************************************/

    75 

    76 #include "qmacdefines_mac.h"

    77 #ifdef QT_MAC_USE_COCOA

    78 

    79 #import <private/qcocoaapplicationdelegate_mac_p.h>

    80 #import <private/qcocoamenuloader_mac_p.h>

    81 #include <private/qapplication_p.h>

    82 #include <private/qt_mac_p.h>

    83 #include <private/qt_cocoa_helpers_mac_p.h>

    84 #include <private/qdesktopwidget_mac_p.h>

    85 #include <qevent.h>

    86 #include <qurl.h>

    87 #include <qapplication.h>

    88 

    89 QT_BEGIN_NAMESPACE

    90 extern void onApplicationChangedActivation(bool); // qapplication_mac.mm

    91 extern void qt_release_apple_event_handler(); //qapplication_mac.mm

    92 QT_END_NAMESPACE

    93 

    94 QT_FORWARD_DECLARE_CLASS(QDesktopWidgetImplementation)

    95 QT_USE_NAMESPACE

    96 

    97 static QT_MANGLE_NAMESPACE(QCocoaApplicationDelegate) *sharedCocoaApplicationDelegate = nil;

    98 

    99 static void cleanupCocoaApplicationDelegate()

   100 {

   101     [sharedCocoaApplicationDelegate release];

   102 }

   103 

   104 @implementation QT_MANGLE_NAMESPACE(QCocoaApplicationDelegate)

   105 

   106 - (id)init

   107 {

   108     self = [super init];

   109     if (self)

   110         inLaunch = true;

   111     return self;

   112 }

   113 

   114 - (void)dealloc

   115 {

   116     sharedCocoaApplicationDelegate = nil;

   117     [dockMenu release];

   118     [qtMenuLoader release];

   119     if (reflectionDelegate) {

   120         [NSApp setDelegate:reflectionDelegate];

   121         [reflectionDelegate release];

   122     }

   123     [super dealloc];

   124 }

   125 

   126 + (id)allocWithZone:(NSZone *)zone

   127 {

   128     @synchronized(self) {

   129         if (sharedCocoaApplicationDelegate == nil) {

   130             sharedCocoaApplicationDelegate = [super allocWithZone:zone];

   131             return sharedCocoaApplicationDelegate;

   132             qAddPostRoutine(cleanupCocoaApplicationDelegate);

   133         }

   134     }

   135     return nil;

   136 }

   137 

   138 + (QT_MANGLE_NAMESPACE(QCocoaApplicationDelegate)*)sharedDelegate

   139 {

   140     @synchronized(self) {

   141         if (sharedCocoaApplicationDelegate == nil)

   142             [[self alloc] init];

   143     }

   144     return [[sharedCocoaApplicationDelegate retain] autorelease];

   145 }

   146 

   147 - (void)setDockMenu:(NSMenu*)newMenu

   148 {

   149     [newMenu retain];

   150     [dockMenu release];

   151     dockMenu = newMenu;

   152 }

   153 

   154 - (NSMenu *)applicationDockMenu

   155 {

   156     return [[dockMenu retain] autorelease];

   157 }

   158 

   159 - (QApplicationPrivate *)qAppPrivate

   160 {

   161     return qtPrivate;

   162 }

   163 

   164 - (void)setQtPrivate:(QApplicationPrivate *)value

   165 {

   166     qtPrivate = value;

   167 }

   168 

   169 - (void)setMenuLoader:(QT_MANGLE_NAMESPACE(QCocoaMenuLoader) *)menuLoader

   170 {

   171     [menuLoader retain];

   172     [qtMenuLoader release];

   173     qtMenuLoader = menuLoader;

   174 }

   175 

   176 - (QT_MANGLE_NAMESPACE(QCocoaMenuLoader) *)menuLoader;

   177 {

   178     return [[qtMenuLoader retain] autorelease];

   179 }

   180 

   181 // This function will only be called when NSApp is actually running. Before

   182 // that, the kAEQuitApplication apple event will be sendt to 

   183 // QApplicationPrivate::globalAppleEventProcessor in qapplication_mac.mm

   184 - (NSApplicationTerminateReply)applicationShouldTerminate:(NSApplication *)sender

   185 {

   186     Q_UNUSED(sender);

   187     // The reflection delegate gets precedence

   188     if (reflectionDelegate

   189         && [reflectionDelegate respondsToSelector:@selector(applicationShouldTerminate:)]) {

   190         return [reflectionDelegate applicationShouldTerminate:sender];

   191     }

   192 

   193     if (qtPrivate->canQuit()) {

   194         if (!startedQuit) {

   195             startedQuit = true;

   196             qAppInstance()->quit();

   197             startedQuit = false;

   198         }

   199     }

   200 

   201     if (qtPrivate->threadData->eventLoops.size() == 0) {

   202         // INVARIANT: No event loop is executing. This probably

   203         // means that Qt is used as a plugin, or as a part of a native

   204         // Cocoa application. In any case it should be fine to 

   205         // terminate now:

   206         return NSTerminateNow;

   207     } else {

   208         // Prevent Cocoa from terminating the application, since this simply

   209         // exits the program whithout allowing QApplication::exec() to return.

   210         // The call to QApplication::quit() above will instead quit the

   211         // application from the Qt side.

   212         return NSTerminateCancel;

   213     }

   214 }

   215 

   216 - (void)applicationDidFinishLaunching:(NSNotification *)aNotification

   217 {

   218     Q_UNUSED(aNotification);

   219     inLaunch = false;

   220     qt_release_apple_event_handler();

   221 }

   222 

   223 - (void)application:(NSApplication *)sender openFiles:(NSArray *)filenames

   224 {

   225     for (NSString *fileName in filenames) {

   226         QString qtFileName = qt_mac_NSStringToQString(fileName);

   227         if (inLaunch) {

   228             // We need to be careful because Cocoa will be nice enough to take

   229             // command line arguments and send them to us as events. Given the history

   230             // of Qt Applications, this will result in behavior people don't want, as

   231             // they might be doing the opening themselves with the command line parsing.

   232             if (qApp->arguments().contains(qtFileName))

   233                 continue;

   234         }

   235         QFileOpenEvent foe(qtFileName);

   236         qt_sendSpontaneousEvent(qAppInstance(), &foe);

   237     }

   238 

   239     if (reflectionDelegate &&

   240         [reflectionDelegate respondsToSelector:@selector(application:openFiles:)])

   241         [reflectionDelegate application:sender openFiles:filenames];

   242 }

   243 

   244 - (BOOL)applicationShouldTerminateAfterLastWindowClosed:(NSApplication *)sender

   245 {

   246     // If we have a reflection delegate, that will get to call the shots.

   247     if (reflectionDelegate

   248         && [reflectionDelegate respondsToSelector:

   249                             @selector(applicationShouldTerminateAfterLastWindowClosed:)])

   250         return [reflectionDelegate applicationShouldTerminateAfterLastWindowClosed:sender];

   251     return NO; // Someday qApp->quitOnLastWindowClosed(); when QApp and NSApp work closer together.

   252 }

   253 

   254 

   255 - (void)applicationDidBecomeActive:(NSNotification *)notification

   256 {

   257     if (reflectionDelegate

   258         && [reflectionDelegate respondsToSelector:@selector(applicationDidBecomeActive:)])

   259         [reflectionDelegate applicationDidBecomeActive:notification];

   260     onApplicationChangedActivation(true);

   261 }

   262 

   263 - (void)applicationDidResignActive:(NSNotification *)notification;

   264 {

   265     if (reflectionDelegate

   266         && [reflectionDelegate respondsToSelector:@selector(applicationDidResignActive:)])

   267         [reflectionDelegate applicationDidResignActive:notification];

   268     onApplicationChangedActivation(false);

   269 }

   270 

   271 - (void)applicationDidChangeScreenParameters:(NSNotification *)notification

   272 {

   273     Q_UNUSED(notification);

   274     QDesktopWidgetImplementation::instance()->onResize();

   275 }

   276 

   277 - (void)setReflectionDelegate:(NSObject <NSApplicationDelegate> *)oldDelegate

   278 {

   279     [oldDelegate retain];

   280     [reflectionDelegate release];

   281     reflectionDelegate = oldDelegate;

   282 }

   283 

   284 - (NSMethodSignature *)methodSignatureForSelector:(SEL)aSelector

   285 {

   286     NSMethodSignature *result = [super methodSignatureForSelector:aSelector];

   287     if (!result && reflectionDelegate) {

   288         result = [reflectionDelegate methodSignatureForSelector:aSelector];

   289     }

   290     return result;

   291 }

   292 

   293 - (BOOL)respondsToSelector:(SEL)aSelector

   294 {

   295     BOOL result = [super respondsToSelector:aSelector];

   296     if (!result && reflectionDelegate)

   297         result = [reflectionDelegate respondsToSelector:aSelector];

   298     return result;

   299 }

   300 

   301 - (void)forwardInvocation:(NSInvocation *)invocation

   302 {

   303     SEL invocationSelector = [invocation selector];

   304     if (reflectionDelegate && [reflectionDelegate respondsToSelector:invocationSelector])

   305         [invocation invokeWithTarget:reflectionDelegate];

   306     else

   307         [self doesNotRecognizeSelector:invocationSelector];

   308 }

   309 

   310 - (void)getUrl:(NSAppleEventDescriptor *)event withReplyEvent:(NSAppleEventDescriptor *)replyEvent

   311 {

   312     Q_UNUSED(replyEvent);

   313 

   314     NSString *urlString = [[event paramDescriptorForKeyword:keyDirectObject] stringValue];

   315     QUrl url(qt_mac_NSStringToQString(urlString));

   316     QFileOpenEvent qtEvent(url);

   317     qt_sendSpontaneousEvent(qAppInstance(), &qtEvent);

   318 }

   319 

   320 @end

   321 #endif